Information Technology Inspiration: Membuat Email pada Oracle

Pada paket UTL_SMTP mulai diperkenalkan pada versi Oracle 8i sehingga dapat digunakan untuk mengirim email dari PL/SQL. Paket UTL_SMTP membutuhkan JServer yang dapat diinstal dengan menjalankan skrip berikut sebagai SYS.

SQL> @$ORACLE_HOME/javavm/install/initjvm.sql

SQL> @$ORACLE_HOME/rdbms/admin/initplsj.sql

BLOB (Binary Large Object) adalah tipe data untuk menyimpan data biner, yang biasa digunakan untuk menyimpan data gambar, audio, maupun video.

Contoh membuat email dengan tipe BLOB pada Oracle :

CREATE OR REPLACE PROCEDURE send_mail (p_to IN VARCHAR2,

p_from IN VARCHAR2,
p_subject IN VARCHAR2,
p_text_msg IN VARCHAR2 DEFAULT NULL,
p_attach_name IN VARCHAR2 DEFAULT NULL,
p_attach_mime IN VARCHAR2 DEFAULT NULL,
p_attach_blob IN BLOB DEFAULT NULL,
p_smtp_host IN VARCHAR2,
p_smtp_port IN NUMBER DEFAULT 25)

l_mail_conn UTL_SMTP.connection;

l_boundary VARCHAR2(50) := '----=*#abc1234321cba#*=';

l_step PLS_INTEGER := 57;

BEGIN

l_mail_conn := UTL_SMTP.open_connection(p_smtp_host, p_smtp_port);

UTL_SMTP.helo(l_mail_conn, p_smtp_host);

UTL_SMTP.mail(l_mail_conn, p_from);

UTL_SMTP.rcpt(l_mail_conn, p_to);

UTL_SMTP.open_data(l_mail_conn);

UTL_SMTP.write_data(l_mail_conn, 'Date: ' || TO_CHAR(SYSDATE, 'DD-MON-YYYY HH24:MI:SS') || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'To: ' || p_to || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'From: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Subject: ' || p_subject || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Reply-To: ' || p_from || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'MIME-Version: 1.0' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: multipart/mixed; boundary="' || l_boundary || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

IF p_text_msg IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: text/plain; charset="iso-8859-1"' || UTL_TCP.crlf || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, p_text_msg);

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf || UTL_TCP.crlf);

END IF;

IF p_attach_name IS NOT NULL THEN

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Type: ' || p_attach_mime || '; name="' || p_attach_name || '"' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Transfer-Encoding: base64' || UTL_TCP.crlf);

UTL_SMTP.write_data(l_mail_conn, 'Content-Disposition: attachment; filename="' || p_attach_name || '"' || UTL_TCP.crlf || UTL_TCP.crlf);

FOR i IN 0 .. TRUNC((DBMS_LOB.getlength(p_attach_blob) - 1 )/l_step) LOOP

UTL_SMTP.write_data(l_mail_conn, UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(DBMS_LOB.substr(p_attach_blob, l_step, i * l_step + 1))) || UTL_TCP.crlf);

END LOOP;

UTL_SMTP.write_data(l_mail_conn, UTL_TCP.crlf);

END IF;

UTL_SMTP.write_data(l_mail_conn, '--' || l_boundary || '--' || UTL_TCP.crlf);

UTL_SMTP.close_data(l_mail_conn);

UTL_SMTP.quit(l_mail_conn);

END;

Cara panggil :

DECLARE

l_name images.name%TYPE := 'site_logo.gif';

l_blob images.image%TYPE;

BEGIN

SELECT image INTO l_blob FROM images WHERE name = l_name;

send_mail(p_to => 'me@ptxzy.com',

p_from => 'admin@ptxzy.com',
p_subject => 'Judul Email',
p_text_msg => 'Isi Email.',
p_attach_name => 'logo.gif',
p_attach_mime => 'image/gif',
p_attach_blob => l_blob,
p_smtp_host => 'smtp.ptxzy.com');

END;

Membuat Email pada Oracle - IV [ BLOB Attachment ]